LTspice : importation d'un modèle de composant

1. Introduction

Cette page montre comment importer dans LTspice un modèle spice d'un composant fourni par un fabricant. La méthode est montrée avec deux exemples : un transistor MOSFET et un Ampli-op.

2. Transistor MOSFET

Les symboles de LTspice sont définis dans des fichier *.asy situés dans le répertoire :

AppData\Local\LTspice\lib\sym

AppData est un répertoire caché situé dans le répertoire personnel de l'utilisateur. Tous les symboles sont donc modifiables par l'utilisateur.

Le symbole qui permet de définir un transistor MOSFET (canal N) est nmos. Voici ce symbole :

LTspice contient déjà des modèles de transistors MOSFET. Pour changer de modèle, cliquer à droite sur le symbole puis cliquer sur le bouton Pick new MOSFET. La liste des modèles disponibles apparaît. Sélectionner le modèle choisi. Voici le nouveau symbole après sélection du modèle IPA030N10 du fabricant Infineon :

Ce symbole ne comporte pas de diode entre la source et le drain alors que les modèles de MOSFET intègrent cette diode (y compris le modèle par défaut).

Nous voulons intégrer un modèle de transistor Infineon ne figurant dans la base de modèles de LTspice. Ces modèles sont téléchargeables librement sur Infineon's Power MOSFET. Nous avons téléchargé le fichier

IFX-SimulationModel_CoolMOS_CE_MOSFETs_500V_Spice-web.lib

qui contient plusieurs modèles de transistors MOSFET. Celui que nous voulons importer est IPP50R500CE. Les fichiers .lib peuvent être placés dans un dossier personnel. Pour importer le modèle dans LTspice ouvrir ce fichier dans LTspice puis aller à la définition du sous-circuit correspondant au composant choisi :

.SUBCKT IPP50R500CE_L0  drain  gate  source

Lg     gate  g1    4n
Ld     drain d1    2.5n
Ls     source s1   2.5n
Rs      s1    s2   2m

Rg     g1    g2     2.21
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP= 4.917  VTO=4.85  THETA=0  VMAX=1.5e5  ETA=0  LEVEL=3)
Rd     d2    d1a    0.513 TC=10m
.MODEL MVDR NMOS (KP=14.79 VTO=-1   LAMBDA=0.2)
Mr d1 d2a d1a d1a MVDR W=1u L=1u
Rx d2a d1a 1m
Cds1 s2 d2 12.9p
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=650   M=0.9  CJO=5.11n  VJ=0.5V)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=452632p  N=2  RS=34u  EG=1.12  TT=250n)
Rdiode  d1  21    30.5m TC=0

.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   0.89n
.MODEL     DGD    D(M=0.88   CJO=0.89n   VJ=0.5)
Rpar      b    d2   1Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    0.56n

.ENDS  IPP50R500CE_L0
				

Cliquer à droite sur la première ligne (.SUBCKT IPP50R500CE_L0 drain gate source) puis sélectionner Create Symbol. Après confirmation, voici le symbole qui apparaît :

Le symbole contient les trois bornes du composant et leur nom (drain, source et gate), le nom du modèle (en bas) et le préfixe du nom qui sera donné au composant dans le schéma (en haut).

Il faut à présent modifier ce symbole pour lui donner l'apparence d'un symbole standard de transistor MOSFET. Il faut donc effacer le cadre rectangulaire et créer le nouveau symbole. Attention : il ne faut pas effacer les trois bornes mais on peut changer chaque label et son ancrage par rapport à la borne. Voici ce qu'on obtient après avoir enlevé le cadre, positionné les bornes à leur emplacement approximatif et renommé leur label :

Il faut à présent dessiner le symbole du transistor. Pour faciliter cette tâche, il peut être intéressant de partir du symbole déjà existant. Pour cela, ouvrir le fichier AppData\Local\LTspice\lib\sym\nmos.asy. Ce fichier est modifiable. Il est donc préférable d'en faire une copie et d'ouvrir la copie. Voici ce qui apparaît dans l'éditeur de symbole :

Nous allons utiliser ce modèle pour dessiner le transistor. Malheureusement, il n'est pas possible de copier ce symbole pour le coller dans la fenêtre IPP50R500CE_L0. Nous devons nous contenter de le copier mentalement. Nous ajoutons aussi la diode source-drain. Remarquons que le dessin doit être positionné par rapport au point d'ancrage, qui est représenté par un cercle et une croix. Nous plaçons ce point d'ancrage à peu près au milieu du symbole. Ce point correspond à la position du pointeur de la souris lorsqu'on place le symbole et sa position précise est sans importance. Voici ce qu'on obtient :

On peut bien sûr alléger le nom du modèle ou rendre invisible les noms des bornes. Le fichier .asy créé se trouve dans :

AppData\Local\LTspice\lib\sym\AutoGenerated

Pour incorporer ce nouveau composant dans un schéma, il suffit donc d'aller le chercher dans le sous-dossier [AutoGenerated].

Voici le contenu du fichier IPP50R500CE_L0.asy :

Version 4
SymbolType BLOCK
LINE Normal -24 32 -32 32
LINE Normal -24 -32 -24 32
LINE Normal -16 24 -16 40
LINE Normal -16 -8 -16 8
LINE Normal -16 -40 -16 -24
LINE Normal 16 32 -16 32
LINE Normal 16 0 16 32
LINE Normal 8 0 16 0
LINE Normal 8 -5 -16 0
LINE Normal 8 6 8 -5
LINE Normal -16 0 8 6
LINE Normal 16 48 16 32
LINE Normal 16 -32 -16 -32
LINE Normal 16 -48 16 -32
LINE Normal 32 32 16 32
LINE Normal 32 -32 32 32
LINE Normal 16 -32 32 -32
LINE Normal 25 6 32 -7
LINE Normal 39 6 25 6
LINE Normal 32 -7 39 6
LINE Normal 39 -7 25 -7
WINDOW 0 -5 -64 Bottom 2
WINDOW 3 5 57 Top 2
SYMATTR Prefix X
SYMATTR Value IPP50R500CE_L0
SYMATTR ModelFile C:\Users\fredl\Documents\Electro\spice\modeles\IFX-SimulationModel_CoolMOS_CE_MOSFETs_500V_Spice-web.lib
PIN 16 -48 LEFT 8
PINATTR PinName D
PINATTR SpiceOrder 1
PIN -32 32 RIGHT 8
PINATTR PinName G
PINATTR SpiceOrder 2
PIN 16 48 LEFT 8
PINATTR PinName S
PINATTR SpiceOrder 3
				  
					  

Si l'on souhaite importer un autre transistor figurant dans le fichier IFX-SimulationModel_CoolMOS_CE_MOSFETs_500V_Spice-web.lib (ou dans un autre fichier du même fabricant), il n'est pas nécessaire de refaire tout le travail précédent. Il suffit de copier le fichier IPP50R500CE_L0.asy et de le renommer avec le nom du nouveau transistor puis, dans ce nouveau fichier, de modifier la ligne SYMATTR Value IPP50R500CE_L0.

3. Amplificateur opérationnel

LTspice comporte des modèles d'ampli-op AD (Analog Device) et LT (Linear Technology) ainsi que des modèles plus généraux intitulés UniversalOpAmp. Voici le schéma d'un ampli-op :

Nous souhaitons importer le modèle spice du TL081 fourni par Texas Instrument. Ce fabricant fournit des modèles pour son logiciel PSPICE mais ils sont utilisables sur tout logiciel spice. Voici le contenu du fichier TL081.lib :

* TL081 OPERATIONAL AMPLIFIER "MACROMODEL" SUBCIRCUIT
* CREATED USING PARTS RELEASE 4.01 ON 06/16/89 AT 13:08
* (REV N/A)      SUPPLY VOLTAGE: +/-15V
* CONNECTIONS:   NON-INVERTING INPUT
*                | INVERTING INPUT
*                | | POSITIVE POWER SUPPLY
*                | | | NEGATIVE POWER SUPPLY
*                | | | | OUTPUT
*                | | | | |
.SUBCKT TL081    1 2 3 4 5

  C1   11 12 3.498E-12
  C2    6  7 15.00E-12
  DC    5 53 DX
  DE   54  5 DX
  DLP  90 91 DX
  DLN  92 90 DX
  DP    4  3 DX
  EGND 99  0 POLY(2) (3,0) (4,0) 0 .5 .5
  FB    7 99 POLY(5) VB VC VE VLP VLN 0 4.715E6 -5E6 5E6 5E6 -5E6
  GA    6  0 11 12 282.8E-6
  GCM   0  6 10 99 8.942E-9
  ISS   3 10 DC 195.0E-6
  HLIM 90  0 VLIM 1K
  J1   11  2 10 JX
  J2   12  1 10 JX
  R2    6  9 100.0E3
  RD1   4 11 3.536E3
  RD2   4 12 3.536E3
  RO1   8  5 150
  RO2   7 99 150
  RP    3  4 2.143E3
  RSS  10 99 1.026E6
  VB    9  0 DC 0
  VC    3 53 DC 2.200
  VE   54  4 DC 2.200
  VLIM  7  8 DC 0
  VLP  91  0 DC 25
  VLN   0 92 DC 25
.MODEL DX D(IS=800.0E-18)
.MODEL JX PJF(IS=15.00E-12 BETA=270.1E-6 VTO=-1)
.ENDS
			 

Pour importer ce modèle dans LTspice, ouvrir ce fichier (qu'on aura pris soin de placer dans un dossier personnel comportant éventuellement d'autres fichiers *.lib) et cliquer à droite sur la ligne .SUBCKT TL081 1 2 3 4 5 puis sélectionner Create Symbol. Après confirmation, voici le symbole qui apparaît :

Les bornes sont définies par un numéro, alors que dans l'exemple précédent elles étaient définies par un nom. Il faut bien sûr consulter le fichier .lib pour connaître la fonction de ces bornes. On enlève le cadre et on change les labels des bornes, ce qui donne :

Il faut ensuite dessiner le symbole. On peut copier le symbole par défaut de LTspice (montré ci-dessus). Voici le résultat :

On peut enlever les légendes des bornes d'alimentation car la borne positive est toujours placée en haut par convention. Pour cela, il faut cliquer à droite sur la borne et sélectionner NONE (Not visible). Voici le résultat :

Il faut noter que si un schéma contient ce symbole, toute modification apportée au symbole dans le fichier TL081.asy se répercute immédiatement sur le schéma.