Réflexion et transmission de l'ionosphère

1. Introduction

L'ionosphère est une partie de la haute atmosphère, située environ entre 80 km et 800 km d'altitude. Le rayonnement UV solaire est très intense à cette altitude et provoque la ionisation partielle de l'oxygène et de l'azote. Il en résulte un état de plasma, qui rend les ondes radio sensibles à l'ionosphère.

Dans la partie la plus ionisée (vers 500 km), la densité totale est de l'ordre de 10¹⁵ /m³ et la densité électronique en plein jour N_e = 10¹²  /m³. La température électronique est de l'ordre de 1000 K.

2. Propagation d'une onde électromagnétique

On considère le modèle le plus simple de propagation d'une onde électromagnétique dans un plasma de faible densité. Le plasma est supposé localement neutre à l'échelle de la longueur d'onde. Le champ magnétique terrestre est négligé. Les interactions entre les charges du plasma sont négligées.

La conductivité du plasma est principalement due aux électrons. En régime sinusoïdal de pulsation ω, l'application de l'équation du mouvement aux électrons conduit à la conductivité suivante :

$$\gamma \left(\omega \right)=\frac{N_e{e}^2}{m_{e}i\omega }$$

Les équations de Maxwell s'écrivent :

$$\begin{array}{cc}\hfill & div\overrightarrow{E}=0\hfill \\ \hfill & \overrightarrow{rot}\overrightarrow{E}=-i\omega B\hfill \\ \hfill & div\overrightarrow{B}=0\hfill \\ \hfill & \overrightarrow{rot}\overrightarrow{B}={\mu }_0\gamma \left(\omega \right)\overrightarrow{E}+{\mu }_0{\epsilon }_{0}i\omega \overrightarrow{E}\hfill \end{array}$$

La recherche d'une onde progressive plane de la forme :

$$\overrightarrow{E}={\overrightarrow{E}}_{0}expi(\omega t-kz)$$

conduit à la relation de dispersion suivante :

$$k^2=\frac{1}{c^2}({\omega }^2-{\omega }_c^2)$$

où la pulsation de coupure est :

$${\omega }_c=\sqrt{\frac{N_e{e}^2}{{\epsilon }_0{m}_e}}$$

Calculons la fréquence de coupure pour la couche la plus ionisée de l'ionosphère :

epsilon0=8.85e-12;
Ne=1e12;
e=1.6e-19;
me=9.1e-31;
c=3e8;
fc=sqrt(Ne*e^2/(epsilon0*me))/(2*%pi)
            

8973209 

Lorsque la fréquence est inférieure à la fréquence de coupure, l'onde est évanescente :

$$\overrightarrow{E}={\overrightarrow{E}}_{0}expi\left(\omega t\right)exp(-\frac{z}{\delta })$$

où δ est la profondeur de pénétration définie par :

$$\delta =\frac{c}{\sqrt{{\omega }_c^2-{\omega }^2}}$$

Pour une fréquence inférieure de 1/1000 à la fréquence de coupure, la profondeur de pénétration est :

delta=c/(2*%pi)/sqrt(fc^2*(1-0.999^2))
            

119.01103 

ce qui est infime à l'échelle de l'ionosphère.

Les ondes radio de fréquence inférieure à 9 MHz ne peuvent donc pas traverser l'ionosphère en plein jour.

Pour calculer les coefficients de réflexion et de transmission de l'ionosphère, on utilisera l'indice de réfraction défini par :

$$\tilde{n}=\frac{ck}{\omega }=\sqrt{1-\frac{{\omega }_c^2}{{\omega }^2}}$$

3. Réflexion sur une couche uniforme

La première approche consiste à considérer l'ionosphère comme un milieu uniforme s'étendant de son altitude inférieure (environ 100 km) à l'infini.

Les coefficients de réflexion sont obtenus avec les relations de Fresnel (réflexion à l'interface de deux milieux transparents). Ces relations, ainsi que la loi de Descartes, sont utilisables avec un indice de réfraction complexe.

On distingue une onde TE, dont le champ électrique est perpendiculaire au plan d'incidence, d'une onde TM, dont le champ électrique est parallèle au plan d'incidence.

Les deux fonctions suivantes calculent les coefficients de réflexion des puissances :

function R=reflexionTE(n1,n2,theta1)
    cosTheta2 = sqrt(1-(n1*sin(theta1)/n2)^2);
    R = abs((n1*cos(theta1)-n2*cosTheta2)/(n1*cos(theta1)+n2*cosTheta2))^2
endfunction
function R=reflexionTM(n1,n2,theta1)
    cosTheta2 = sqrt(1-(n1*sin(theta1)/n2)^2);
    R = abs((n2*cos(theta1)-n1*cosTheta2)/(n2*cos(theta1)+n1*cosTheta2))^2
endfunction
function n=indice(f)
    n = sqrt(1-1/f^2)
endfunction
            

On trace tout d'abord le coefficient de réflexion (à partir de l'air d'indice 1) en incidence normale en fonction de la fréquence :

f = linspace(0.1,3,200);
np = length(f);
R = zeros(np);
for i=1:np,
    R(i)=reflexionTE(1,indice(f(i)),0);
end,
            

plotA=scf();
plot2d(f,R,style=5);
xtitle('Incidence theta = 0','f/fc','R');
            

Figure pleine page

En dessous de la fréquence de coupure, l'indice est imaginaire pur, ce qui se traduit par une réflexion totale d'une onde en provenance du sol. Si la fréquence est supérieure à 9x1.6 = 14 MHz, l'indice est réel et proche de 1 : l'onde traverse l'ionosphère sans atténuation.

Juste au dessus de la fréquence de coupure, l'indice du plasma est réel mais inférieur à 1. Il y a donc une réflexion totale pour un angle d'incidence vérifiant :

$$sin{\theta }_t=n$$

Voyons le coefficient de réflexion pour un angle d'incidence de 45 degrés (ondes TE et TM) :

RTE=zeros(np);
RTM=zeros(np);
for i=1:np,
    RTE(i)=reflexionTE(1,indice(f(i)),45/180*%pi);
    RTM(i)=reflexionTM(1,indice(f(i)),45/180*%pi);
end,
            

plotB=scf();
plot2d(f,RTE,style=4);
plot2d(f,RTM,style=5);
legend('TE','TM');
xtitle('Incidence theta = 45','f/fc','R');
            

Figure pleine page

Pour cet angle d'incidence, la coupure effective est donc augmentée de 1.5. Pour un angle d'incidence donné, il y a réflexion totale tant que :

$$n<sin\theta$$

La condition s'écrit :

$$f<\frac{f_c}{\sqrt{1-{sin}^2\theta }}$$

4. Modèle à indice continu

En réalité, la densité électronique de l'ionosphère varie continûment, avec un maximum de l'ordre de 10¹² /m³ (en plein jour). L'échelle spatiale de variation de la densité est bien plus grande que la longueur d'onde. La réflexion observée sur le modèle précédent au dessus de la fréquence de coupure n'est donc pas pertinente, puisqu'elle provient d'une dicontinuité de l'indice.

On modélise la densité par un profil parabolique, atteignant son maximum au milieu de l'ionosphère. Le carré de l'indice de réfraction prend alors la forme :

$$n^2=1-\frac{f_{cm}^2}{f^2}\left(1-\frac{4}{h}{(z-\frac{h}{2})}^2\right)$$

f_cm est la fréquence de coupure maximale, correspondant au maximum de densité. Aux bords de l'ionosphère (z=0 et z=h), l'indice est 1.

La méthode de calcul est une résolution numérique des équations de Maxwell dans un milieu stratifié.

La longueur d'onde (dans le vide) λ_c pour la fréquence de coupure est prise comme échelle de longueur.

La fonction suivante calcule le coefficient de réflexion (onde TE) pour une fréquence et un angle d'incidence donnés. La fréquence est relative à la fréquence de coupure. La hauteur h est relative à la longueur d'onde λ_c (environ 30 m).

Le calcul sur une épaisseur de l'ordre de 1000 km étant trop long, on se limite à une épaisseur plus modeste, suffisante pour mettre en évidence le comportement de l'ionosphère.

function r=reflexion(f,theta)
    k=2*%pi*f;
    h=100;
    alpha2=sin(theta)^2;
    function n2=indice2(z)
        n2=1-1/f^2*(1-4/h^2*(z-h/2)^2)
    endfunction
    function [deriv]=systeme(z,y)
        deriv(1)=k*y(4),
        deriv(2)=-k*y(3),
        deriv(3)=k*(indice2(z)-alpha2)*y(2),
        deriv(4)=-k*(indice2(z)-alpha2)*y(1),
    endfunction 
    z=[0,h];
    tolA=1d-4;
    tolR=1d-10;
    %ODEOPTIONS=[1,0,0,%inf,0,0,1e9,12,5,0,-1,-1];
    V1=ode('stiff',[1;0;0;0],0,z,tolR,tolA,systeme);
    V2=ode('stiff',[0;0;1;0],0,z,tolR,tolA,systeme);
    p=length(z);
    M=[V2(3,p)+%i*V2(4,p), -V2(1,p)-%i*V2(2,p); -V1(3,p)-%i*V1(4,p), V1(1,p)+%i*V1(2,p)];
    r=((M(1,1)+M(1,2))-(M(2,1)+M(2,2)))/((M(1,1)+M(1,2))+(M(2,1)+M(2,2)))
endfunction
            

On trace le coefficient de réflexion en puissance en fonction de la fréquence :

f=linspace(0.5,1.5,300);
np=length(f);
R=zeros(np);
angle=0;
for i=1:np,
    R(i)=abs(reflexion(f(i),angle))^2;
end,
            

plotC=scf();
plot2d(f,R,style=4);
plot2d(f,R,style=5);
xtitle('Incidence theta = 0','f/fc','R');
            

Figure pleine page

Comme attendu, le coefficient de réflexion chute à une valeur négligeable juste au dessus de la fréquence de coupure.

Voyons si le phénomène de réflexion totale se manifeste :

f=linspace(1,2,1000);
np=length(f);
R=zeros(np);
angle=45*%pi/180;
for i=1:np,
    R(i)=abs(reflexion(f(i),angle))^2;
end,
            

plotD=scf();
plot2d(f,R,style=4);
plot2d(f,R,style=5);
xtitle('Incidence theta = 45 (onde TE)','f/fc','R');
            

Figure pleine page

La transition est bien décalée, mais un peu moins que dans le modèle à une couche. Il y a de plus des oscillations au dessus de la coupure. Cependant, le modèle utilisé suppose une onde plane. En pratique, les faisceaux émis par les antennes ont une extension limitée par rapport à l'épaisseur de l'ionosphère.