Table des matières Scilab

Couches semi-réfléchissantes

1. Introduction

Une couche mince semi-réfléchissante déposée sur la surface d'une lame de verre permet d'obtenir un diviseur de faisceau. Par exemple, l'interféromètre de Michelson fonctionne avec ce type de lame.

La couche est soit métallique soit diélectrique. On considère tout d'abord le cas d'une monocouche déposée sur un substrat en verre, puis un système multicouches périodique, à l'aide de la théorie des structures multicouches.

2. Couche métallique

On considère le cas de l'aluminium, utilisé généralement pour les revêtements des miroirs en raison de sa relative neutralité de couleur. Son indice de réfraction complexe à 590 nm est ([1] p.69) :

On cherche tout d'abord l'épaisseur de la couche permettant d'obtenir une réflexion de puissance égale à la transmission. On se place à l'angle d'incidence de 45 degrés, auquel les lames semi-réfléchissantes sont le plus souvent utilisées. On considère seulement la polarisation TE (perpendiculaire au plan d'incidence). L'indice du substrat est 1.5.

La fonction suivante fournit les coefficients de réflexion et de transmission pour plusieurs épaisseurs (relatives à la longueur d'onde) :

getf('multilayer.sci');
function [R,T]=reflexionMetal(e)
    npts=length(e);
    R=zeros(npts);
    T=zeros(npts);
    for p=1:npts,
        [R(p),T(p)]=coefficientsRTpuissances(1,1,%pi/4,1.5,1,[1.44-%i*5.32,e(p)]);
    end,
endfunction
            

Tracé de ces coefficients en fonction du rapport e/λ :

e=[0:0.0005:0.02];
[R,T]=reflexionMetal(e);
            
plotA=scf();
plot2d(e,R,style=5);
plot2d(e,T,style=9);
legend('R','T');
xtitle('Aluminium','e/lambda','');
            
../../../../figures/sciphys/optique/semireflex/plotA.svgFigure pleine page

L'égalité de la réflexion et de la transmission est obtenue pour une épaisseur (en nanomètres) :

e=0.0078;
equ=e*589
4.5942 

Pour cette épaisseur, environ 80 pour cent de la puissance incidente est réfléchie ou transmise, le reste étant absorbé dans la couche métallique.

Remarque : pour une épaisseur si faible, l'indice complexe de la couche d'aluminium est probablement différente de la valeur utilisée ici, qui résulte de mesures de coefficients de réflexion d'une couche épaisse.

La fonction suivante permet d'obtenir l'influence de l'angle d'incidence sur le coefficient de réflexion et de transmission, toujours en polarisation TE :


function [R,T]=reflexionSemiRef(thetai)
    npts=length(thetai);
    R=zeros(npts);
    T=zeros(npts);
    for p=1:npts,
        [R(p),T(p)]=coefficientsRTpuissances(1,1,thetai(p),1.5,1,[1.44-%i*5.32,e]);
    end,
endfunction
            

On trace les coefficients en fonction de l'angle d'incidence :

thetai=[0:1:90];
[R,T]=reflexionSemiRef(thetai*%pi/180);
            
plotB=scf();
plot2d(thetai,R,style=5);
plot2d(thetai,T,style=9);
legend('R','T');
xtitle('Aluminium','theta');
            
../../../../figures/sciphys/optique/semireflex/plotB.svgFigure pleine page

L'égalité de la transmission et de la réflexion est obtenue seulement au voisinage de l'angle de 45 degrés.

La fonction suivante permet d'obtenir le déphasage à la réflexion pour l'onde TE et pour l'onde TM, en fonction de l'angle d'incidence :


function [phiTE,phiTM]=dephasage(thetai)
    npts=length(thetai);
    phiTE=zeros(npts);    phiTM=zeros(npts);
    for p=1:npts,
        [r,t]=coefficientsRT(1,1,thetai(p),1.5,1,[1.44-%i*5.32,e]);
        phiTE(p)=imag(log(r));
        [r,t]=coefficientsRT(1,1,thetai(p),1.5,0,[1.44-%i*5.32,e]);
        phiTM(p)=imag(log(r));
    end,
endfunction
            
thetai=[40:0.1:50];
[phiTE,phiTM]=dephasage(thetai);
plotC=scf();
plot2d(thetai,phiTE/%pi,style=5,rect=[40,-1,50,1]);
plot2d(thetai,phiTM/%pi,style=9);
legend('phiTE','phiTM');
xtitle('Aluminium','theta','phi/pi');
            
../../../../figures/sciphys/optique/semireflex/plotC.svgFigure pleine page

Pour la polarisation perpendiculaire au plan d'incidence (TE), le déphasage reste assez proche de π. Pour l'onde TM, les variations du déphasage sont beaucoup plus importantes. Il s'en suit qu'une polarisation incidente rectiligne (autre que TE ou TM) est réfléchie en polarisation elliptique.

3. Couche diélectrique

Une monocouche d'un matériau diélectrique de fort indice de réfraction permet d'effectuer une séparation du faisceau incident sans pertes d'énergie.

La simulation suivante trace les coefficients de réflexion et de transmission en fonction de l'épaisseur de la couche.

CoucheMince.swfFigure pleine page

Pour un indice de 2.4 environ, certaines épaisseurs permettent d'obtenir une division 50/50 pour un angle d'incidence de 45 degrés.

La maximum de réflexion est obtenue lorsque :

où l'angle de θ est obtenu à partir de l'angle d'incidence par la loi de Descartes :

La fonction suivante calcule l'épaisseur la plus petite vérifiant cette condition (couche quart d'onde) :


function e=epaisseurMaxReflex(lambda,thetai,n)
    cosTheta=sqrt(1-(sin(thetai)/n)^2);
    e=lambda/4/(n*cosTheta)
endfunction
            

Pour un angle d'incidence et une longueur d'onde donnés, la fonction suivante calcule le coefficient de réflexion maximal (onde TE) pour différentes valeurs de l'indice :


function R=coefMaxReflex(lambda,thetai,n)
    npts=length(n);
    R=zeros(npts);
    for p=1:npts,
        [R(p),T]=coefficientsRTpuissances(lambda,1,thetai,1.5,1,[n(p),epaisseurMaxReflex(lambda,thetai,n(p))]);
    end,
endfunction
            

On trace ce coefficient de réflexion maximal pour une longueur d'onde de 500 nm et un angle de 45 degrés :

n=[1:0.01:3];
R=coefMaxReflex(500,%pi/4,n);
            
plotD=scf();
plot2d(n,R,style=5);
xtitle('dielectrique : R maximal','n','R');
            
../../../../figures/sciphys/optique/semireflex/plotD.svgFigure pleine page

Un coefficient de réflexion de 0.5 est obtenu pour un indice 2.43. Pour une épaisseur, un indice et un angle d'incidence fixés, la fonction suivante calcule ce coefficient de réflexion en fonction de la longueur d'onde :


function R=coefMaxReflexB(lambda,thetai,n,e)
    npts=length(lambda);
    R=zeros(npts);
    for p=1:npts,
        [R(p),T]=coefficientsRTpuissances(lambda(p),1,thetai,1.5,1,[n,e]);
    end,
endfunction
            

On trace le coefficient de réflexion sur le spectre visible :


n=2.43;
e=epaisseurMaxReflex(500,%pi/4,n);
lambda=[400:1:700];
R=coefMaxReflexB(lambda,%pi/4,n,e);
            
plotE=scf();
plot2d(lambda,R,style=5,rect=[400,0,700,0.5]);
xtitle('dielectrique : R maximal','lambda','R')
            
../../../../figures/sciphys/optique/semireflex/plotE.svgFigure pleine page

Le coefficient de réflexion reste voisin de 0.5 sur tout le spectre visible. L'inconvénient de la technique monocouche est qu'elle nécessite un diélectrique d'indice de réfraction élevé.

4. Multicouche périodique

Le film déposé sur le substrat en verre est composé d'une alternance périodique de deux couches de diélectriques, l'une d'indice n1, l'autre d'indice n2 plus faible.

Chaque couche a une épaisseur optique égale au quart de la longueur d'onde (par exemple 500 nm) pour l'angle d'incidence de 45 degrés.

La fonction suivante construit la définition d'un système à N périodes :


function sys=multicouchePeriodique(lambda,N,n1,n2)
    e1=epaisseurMaxReflex(lambda,%pi/4,n1);
    e2=epaisseurMaxReflex(lambda,%pi/4,n2);
    sys=zeros(2*N,2);
    for c=1:N,
        sys(2*c-1,1)=n1;
        sys(2*c-1,2)=e1;
        sys(2*c,1)=n2;
        sys(2*c,2)=e2;
    end,
endfunction
            

La fonction suivante calcule le coefficient de réflexion pour différentes longueurs d'onde :


function R=coefReflexion(lambda,sys)
    npts=length(lambda);
    R=zeros(npts);
    for p=1:npts,
        [R(p),T]=coefficientsRTpuissances(lambda(p),1,%pi/4,1.5,1,sys);
    end,
endfunction
            

Comme exemple, on considère une alternance de couches d'indices 1.8 et 1.4 :


lambda=[400:1:700];
n1=1.8;
n2=1.4;
sys1=multicouchePeriodique(500,1,n1,n2);
R1=coefReflexion(lambda,sys1);
sys2=multicouchePeriodique(500,2,n1,n2);
R2=coefReflexion(lambda,sys2);
sys3=multicouchePeriodique(500,3,n1,n2);
R3=coefReflexion(lambda,sys3);
sys4=multicouchePeriodique(500,20,n1,n2);
R4=coefReflexion(lambda,sys4);
            
plotF=scf();
plot2d(lambda,R1,style=5,rect=[400,0,700,1]);
plot2d(lambda,R2,style=9);
plot2d(lambda,R3,style=12);
plot2d(lambda,R4,style=15);
legend('N=1','N=2','N=3','N=20');
xtitle('Multicouche periodique : n1=1.8 n2=1.4','lambda (nm)','R');
            
../../../../figures/sciphys/optique/semireflex/plotF.svgFigure pleine page

En jouant sur le nombre de couches ou sur leurs indices, on peut obtenir la réflexion de 0.5 pour la longueur d'onde de 500 nm. En revanche, la variation avec la longueur d'onde est plus grande que pour un film monocouche.

Si on augmente le nombre de couches, le coefficient de réflexion augmente, jusqu'à des valeurs proches de 1. Ce type de film permet d'obtenir un très bon réflecteur achromatique sur un large domaine de longueurs d'ondes.

Références
[1]  F. Desvignes,  Rayonnements optiques,  (Masson, 1997)
Creative Commons LicenseTextes et figures sont mis à disposition sous contrat Creative Commons.