Table des matières PDFScilab

Cinétique de réactions consécutives

1. Équations différentielles

On considère les réactions d'ordre 1 consécutives suivantes :

Si on note a, b et c les concentrations, le système d'équations différentielles est :

2. Simulation

La simulation suivante effectue la résolution numérique du système différentiel. On peut modifier les constantes de vitesse, les conditions initiales, le temps final du calcul, le nombre de points tracés et la précision (supérieure à 3). L'échelle des courbes peut être modifiée. Pour imprimer la figure, appuyer sur F1.

Consecutives.swfFigure pleine page

3. Résolution numérique avec Scilab

Fonction de résolution et de tracé


function tracer(k1,k2,tmax,init)
 function [yd]=systeme(t,y)
  yd(1)=-k1*y(1)
  yd(2)=k1*y(1)-k2*y(2)
  yd(3)=k2*y(2)
 endfunction
 rtol=1d-4;
 atol=[1d-4; 1d-4; 1d-4];
 t=[0:tmax/300:tmax];
 y=ode(init,0,t,rtol,atol,systeme);
 a=y(1,:);
 b=y(2,:);
 c=y(3,:);
 plot2d(t,a,style=color('red')) 
 plot2d(t,b,style=color('seagreen')) 
 plot2d(t,c,style=color('royalblue'))
    legends(['a','b','c'],[color('red'),color('seagreen'),color('royalblue')])
endfunction
            

4. Exemples

Initialement a = 1 et b = c = 0. Les deux réactions ont la même constante de vitesse.

plotA=scf();
init=[1;0;0]; tmax=10;
tracer(1,1,tmax,init)
xtitle('k1 = 1, k2 = 1','t')
            
plotA.pngplotA.pdf

La concentration de l'espèce intermédiaire B passe par un maximum.

Augmentons la constante de vitesse de la deuxième réaction :

plotB=scf();
init=[1;0;0]; tmax=10;
tracer(1,4,tmax,init)
xtitle('k1 = 1, k2 = 4','t')
            
plotB.pngplotB.pdf

Le maximum arrive plus tôt et sa hauteur est moindre.

Lorsque la constante k2 est beaucoup plus grande que k1, la première étape est limitante :

plotC=scf();
init=[1;0;0]; tmax=10;
tracer(1,50,tmax,init)
xtitle('k1 = 1, k2 = 50','t')
            
plotC.pngplotC.pdf

Dans ce cas, la concentration de l'intermédiaire B atteint rapidement son maximum, et sa concentration reste très faible. On a donc l'approximation suivante :

qui montre que les vitesses de disparition de A et d'apparition de B sont pratiquement égales. On peut également écrire :

Lorsque la formation d'un intermédiare est difficile par rapport à sa disparition (comparaison des constantes de vitesse), l'approximation des régimes quasi-stationnaires consiste à considérer que la vitesse de formation de cet intermédiaire est égale à sa vitesse de disparition.

On peut considérer aussi la situation inverse où la deuxième réaction est limitante :

plotD=scf();
init=[1;0;0]; tmax=5;
tracer(50,1,tmax,init)
xtitle('k1 = 50, k2 = 1','t')
            
plotD.pngplotD.pdf
Creative Commons LicenseTextes et figures sont mis à disposition sous contrat Creative Commons.