Particule chargée dans le champs de deux charges égales

1. Introduction

Ce document traite le mouvement d'une particule chargée dans le champ créé par deux charges ponctuelles identiques. Le mouvement est considéré dans un plan contenant les deux charges. Il s'agit du problème des trois corps en interaction newtonienne, avec deux corps fixés.

2. Champ électrostatique

On se place dans un plan contenant les deux charges, dans lequel on utilise un repère (0xy). Les deux charges A et B sont placées sur l'axe x respectivement en x=-a et x=+a. Le potentiel électrostatique dans le plan est :

$$V(x,y)=\frac{q_0}{4\pi {\epsilon }_0}(\frac{1}{\sqrt{{(x-a)}^2+y^2}}+\frac{1}{\sqrt{{(x+a)}^2+y^2}})\text{(1)}$$

Pour le calcul numérique, on considère les coordonnées réduites par a et le potentiel réduit par

$$V_0=\frac{q_0}{4\pi {\epsilon }_{0}a}\text{(2)}$$

V=1/Sqrt[(x-1)^2+y^2]+1/Sqrt[(x+1)^2+y^2]
m = 5
            

On commence par tracer la surface définie par ce potentiel :

Plot3D[V,{x,-m,m},{y,-m,m},PlotRange->{{-m,m},{-m,m},{0,10}}]

figA.pdf

Le champ électrique est obtenu par le gradient du potentiel :

Ex=-D[V,x]
Ey=-D[V,y]
            

On trace le champ E_y sur la médiatrice des deux charges (axe de symétrie) :

Plot[Ey/.{x->0},{y,-m,m},AxesLabel->{"y","Ey"}]

figB.pdf

Enfin le tracé des lignes de champ :

StreamPlot[{Ex,Ey},{x,-m,m},{y,-m,m},StreamPoints->Fine,AxesLabel->{"x","y"}]

figC.pdf

3. Mouvement d'une particule chargée

Le système d'équations du mouvement de la particule chargée (système du premier ordre) est :

$$\begin{array}{ccc}\hfill & \frac{dx}{dt}=v_x\hfill & \hfill \text{(3)}\\ \hfill & \frac{d{v}_x}{dt}=-\frac{q}{m}\frac{\partial V}{\partial x}\hfill & \hfill \text{(4)}\\ \hfill & \frac{dy}{dt}=v_y\hfill & \hfill \text{(5)}\\ \hfill & \frac{d{v}_y}{dt}=-\frac{q}{m}\frac{\partial V}{\partial y}\hfill & \hfill \text{(6)}\end{array}$$

La particule (de charge négative) est placée initialement en un point proche de l'axe Oy :

b=-1
x0=0.2
y0=5
m=5
equation={x'[t]==vx[t],vx'[t]==b*Ex/.{x->x[t],y->y[t]},y'[t]==vy[t],vy'[t]==b*Ey/.{x->x[t],y->y[t]},x[0]==x0,vx[0]==0,y[0]==y0,vy[0]==0}
tmax = 50
sol = NDSolve[equation,{x[t],vx[t],y[t],vy[t]},{t,0,tmax}]
            

ParametricPlot[{x[t],y[t]}/.sol,{t,0,tmax},PlotPoints->1000,PlotRange->{{-m,m},{-m,m}},AspectRatio->1]

figD.pdf

La particule se rapproche de l'axe sous l'effet des lignes de champ qui convergent vers le centre. Lorsque l'axe Ox contenant les charges est franchi, la particule s'éloigne de l'axe puis est rarentie jusqu'à être attirée vers la charge située B en x=1. Elle subit une diffusion par cette charge puis s'éloigne à nouveau avant de revenir et de subir une deuxième diffusion.

On prolonge la durée du calcul pour voir la suite de la trajectoire :

tmax = 200
sol = NDSolve[equation,{x[t],vx[t],y[t],vy[t]},{t,0,tmax}]
             

ParametricPlot[{x[t],y[t]}/.sol,{t,0,tmax},PlotPoints->1000,PlotRange->{{-m,m},{-m,m}},AspectRatio->1]

figE.pdf

La particule revient régulièrement vers la charge B au voisinage de laquelle elle subit une diffusion qui dévie fortement sa trajectoire. Ce mouvement est très différent de celui qui serait obtenu avec une seule charge : on aurait alors une diffusion dans un champ coulombien, c'est-à-dire une trajectoire conique.

Pour voir si le mouvement est périodique, on trace la composante sur x sur une plus grande durée :

tmax=4000
sol = NDSolve[equation,{x[t],vx[t],y[t],vy[t]},{t,0,tmax},
                Method->{"ExplicitRungeKutta","DifferenceOrder"->5},
                AccuracyGoal->6,PrecisionGoal->6]
              

Plot[x[t]/.sol,{t,0,tmax},PlotPoints->1000,AxesLabel->{"t","x"},PlotRange->{{0,tmax},{-5,5}}]

figF.pdf

Le mouvement n'est pas périodique mais les éloignements de grande amplitude se produisent avec régularité. Pour vérifier la bonne conduite de l'intégration numérique, on trace l'énergie mécanique en fonction du temps :

energie=1/2*(vx[t]^2+vy[t]^2)-V/.{x->x[t],y->y[t]}
              

Plot[energie/.sol,{t,0,tmax},PlotPoints->1000,AxesLabel->{"t","x"},PlotRange->{{0,tmax},{-0.5,0}}]

figG.pdf

L'énergie mécanique est globalement constante sur cet intervalle de temps, mais il y a des petits sauts d'énergie qui montrent que la méthode utilisée (méthode de Runge Kutta explicite) n'est pas parfaite pour ce problème. Vers la fin de l'intervalle de temps, on observe une divergence de l'énergie qui est typique d'une instabilité numérique. Pour ce type de problème, une méthode d'intégration symplectique est préférable.