Réflexion et transmission d'un milieu absorbant

2.a. Coefficients de réflexion

On considère le milieu absorbant formant un demi-espace. La surface est supposée plane et non diffusante (réflexion spéculaire). Les coefficients de réflexion à partir du vide sont donnés par les relations de Fresnel.

En pratique, pour mesurer ce coefficient de réflexion sur des matériaux peu absorbants, il faut utiliser une face d'un prisme du matériau. En effet, l'utilisation d'une lame à faces parallèles conduit à des réflexions multiples avec interférences. Pour un matériau fortement absorbant, il suffit d'utiliser une lame d'épaisseur suffisante pour absorber complètement l'onde transmise.

Les deux fonctions suivantes calculent les coefficients de réflexion en puissance (ondes TE et TM) en fonction de l'indice du milieu d'incidence, de l'indice du milieu absorbant et de l'angle d'incidence :

function R=reflexionTE(n1,n2,theta1)
    cosTheta2=sqrt(1-(n1*sin(theta1)/n2)^2);
    R=abs((n1*cos(theta1)-n2*cosTheta2)/(n1*cos(theta1)+n2*cosTheta2))^2
endfunction
function R=reflexionTM(n1,n2,theta1)
    cosTheta2=sqrt(1-(n1*sin(theta1)/n2)^2);
    R=abs((n2*cos(theta1)-n1*cosTheta2)/(n2*cos(theta1)+n1*cosTheta2))^2
endfunction
            

2.b. Incidence normale

En incidence normale, le coefficient de réflexion des puissances est :

$$R=\frac{{(1-n)}^2+{\kappa }^2}{{(1+n)}^2+{\kappa }^2}$$

On étudie tout d'abord l'influence de la partie imaginaire de l'indice complexe. La fonction suivante fournit un vecteur de coefficients de réflexion pour un vecteur de κ donné :

function [R]=reflexNormale(n,kappa)
    npts=length(kappa);
    R=zeros(npts);
    for p=1:npts,
        R(p)=reflexionTE(1,n-%i*kappa(p),0);
    end,
endfunction
                

On trace le coefficient de réflexion pour différentes valeurs de l'indice n :

kappa=[0:0.01:10];

plot1=scf();
plot2d(kappa,reflexNormale(0.5,kappa),style=4,rect=[0,0,10,1.5]);
plot2d(kappa,reflexNormale(1,kappa),style=5);
plot2d(kappa,reflexNormale(2,kappa),style=6);
plot2d(kappa,reflexNormale(4,kappa),style=9);
xtitle('','K','R');
legend('n=0.5','n=1','n=2','n=4');
                

Figure pleine page

Un bon réflecteur est généralement obtenu avec un coefficient κ supérieur à 1. On parle dans ce cas de réflexion métallique. Par exemple, pour l'aluminium à 590 nm, le coefficient de réflexion est :

R=reflexNormale(1.44,5.32)

0.8318543 

Inversement, la réflexion vitreuse est obtenue lorsque le coefficient κ est petit devant l'indice n. Par exemple : l'eau à une fréquence de 10 GHz :

R=reflexNormale(8,1.2)

0.6118389 

Dans ce cas, la réflexion est principalement due à la permittivité élevée de l'eau (partie réelle de ε_r)

Ces deux exemples montrent que la mesure seule du coefficient de réflexion ne permet pas de conclure sur l'importance relative de n et κ.

3.a. Principe

Avec une lame à faces parallèles du matériau absorbant, il est possible de mesurer le coefficient de réflexion R et de transmission T. L'absorption dans la lame est donnée par :

$$A=1-R-T$$

Pour le calcul, on utilise la théorie des systèmes multicouches.

Le module scilab multilayer.sci permet de calculer les coefficients de réflexion et de transmission d'une structure multicouches.

La longueur d'onde est prise comme unité de longueur pour l'épaisseur de la lame. La fonction suivante calcule les coefficient de réflexion, de transmission et d'absorption en incidence normale (puissances), pour différentes valeurs de l'épaisseur. Le milieu extérieur est l'air.

getf('multilayer.sci');
function [R,T,A]=reflexionLame(n,kappa,e)
    npts=length(e);
    R=zeros(npts);
    T=zeros(npts);
    A=zeros(npts);
    for p=1:npts,
        [R(p),T(p)]=coefficientsRTpuissances(1,1,0,1,1,[n-%i*kappa,e(p)]);
        A(p)=1-T(p)-R(p);
    end,
endfunction
            

3.b. Matériau faiblement absorbant

Dans ce cas, la réflexion est principalement causée par l'indice n, lorsqu'il est différent de 1.

e=[0:0.001:2];
[R1,T1,A1]=reflexionLame(2,0.1,e);
[R2,T2,A2]=reflexionLame(2,0.2,e);
[R3,T3,A3]=reflexionLame(2,0.5,e);
            

plotB=scf();
plot2d(e,R1,style=5,rect=[0,0,2,1]);
plot2d(e,R2,style=6);
plot2d(e,R3,style=9);
legend('n=2, K=0.1','n=2, K=0.2', 'n=2, K=0.5');
xtitle('Reflexion','e/lambda','R');
            

Figure pleine page

plotC=scf();
plot2d(e,T1,style=5,rect=[0,0,2,1]);
plot2d(e,T2,style=6);
plot2d(e,T3,style=9);
legend('n=2, K=0.1','n=2, K=0.2', 'n=2, K=0.5');
xtitle('Transmission','e/lambda','R');
            

Figure pleine page

plotD=scf();
plot2d(e,A1,style=5,rect=[0,0,2,1.5]);
plot2d(e,A2,style=6);
plot2d(e,A3,style=9);
legend('n=2, K=0.1','n=2, K=0.2', 'n=2, K=0.5');
xtitle('Absorption','e/lambda','R');
            

Figure pleine page

Pour une épaisseur inférieure à la longueur d'onde, le coefficient de réflexion présente des oscillations importantes en fonction de l'épaisseur. Ces oscillations sont la conséquence des réflexions multiples, qui deviennent négligeables seulement lorsque l'épaisseur est suffisante pour absorber complètement l'onde. La réflexion est très faible pour une épaisseur égale au quart et à la moitié de la longueur d'onde. Pour effectuer des mesures, il est préférable de ce placer sur un maximum de réflexion, par exemple :

$$e=\frac{3}{8}\lambda$$

3.c. Matériau fortement absorbant

e=[0:0.001:0.5];
[R1,T1,A1]=reflexionLame(2,2,e);
[R2,T2,A2]=reflexionLame(2,3,e);
[R3,T3,A3]=reflexionLame(2,5,e);
            

plotE=scf();
plot2d(e,R1,style=5,rect=[0,0,0.5,1]);
plot2d(e,R2,style=6);
plot2d(e,R3,style=9);
legend('n=2, K=2','n=2, K=3', 'n=2, K=5');
xtitle('Reflexion','e/lambda','R');
            

Figure pleine page

plotF=scf();
plot2d(e,T1,style=5,rect=[0,0,0.5,1]);
plot2d(e,T2,style=6);
plot2d(e,T3,style=9);
legend('n=2, K=2','n=2, K=3', 'n=2, K=5');
xtitle('Transmission','e/lambda','R');
            

Figure pleine page

plotG=scf();
plot2d(e,A1,style=5,rect=[0,0,0.5,1.5]);
plot2d(e,A2,style=6);
plot2d(e,A3,style=9);
legend('n=2, K=2','n=2, K=3', 'n=2, K=5');
xtitle('Absorption','e/lambda','R');
            

Figure pleine page

Dans ce cas, la mesure de la transmission nécessite des épaisseurs beaucoup plus faible. En revanche, le coefficient de réflexion ne présente pas de minima.

3.d. Exemple : eau

Dans le domaine des micro-ondes à, l'eau possède à la fois un indice n élevé et un indice d'atténuation κ non négligeable. Des données complètes sur l'eau sont présentées dans Water structure and science. À 10 GHz, la permittivité relative de l'eau à 20 degrés celcius est

$$\underline{{\epsilon }_r}=60-30i$$

L'indice complexe est donc :

$$\underline{n}=\sqrt{\underline{{\epsilon }_r}}=8-1.9i$$

e=[0:0.001:0.5];
[R1,T1,A1]=reflexionLame(8,1.9,e);
                

plotH=scf();
plot2d(e,R1,style=5,rect=[0,0,0.5,1]);
plot2d(e,T1,style=9);
plot2d(e,A1,style=14);
legend('R','T','A');
xtitle('Eau (10 GHz)','e/lambda','');
                

Figure pleine page

Le coefficient de transmission est non nul pour des épaisseurs inférieures à environ 5 mm. Pour ce type de matériau, les mesures de R et T à une épaisseur arbitraire ne donnent aucune information directement utilisable. Il faut mesurer ces coefficients pour différentes épaisseurs et ajuster les données avec ces courbes théoriques.

3.e. Simulation

Figure pleine page